Автоматически отвечайте на электронные письма с помощью Mail, AppleScript и Automator.

Вы можете сделать это следующим образом:

property the_numbers : {10000, 20000, 30000}
using terms from application "Mail"
    on perform mail action with messages theMessages for rule theRule
        repeat with i from 1 to count of theMessages
            tell application "Mail"
                set the_sender to sender of item i of theMessages
                set the_subject to subject of item i of theMessages
                set the_counter to item 1 of the_numbers
                -- make the outgoing message (the reply)
                set the_reply to make new outgoing message with properties ¬
                    {subject:"Re: " & the_subject, content:"Use this number-- " & the_counter}
                tell the_reply
                    make new to recipient at end of to recipients with properties {address:the_sender}
                end tell
                send the_reply
            end tell
            -- this is the step that deletes item 1 from the list 
            set the_numbers to items 2 thru -1 of the_numbers
        end repeat
    end perform mail action with messages
end using terms from

Это работает, но вам придется немного поработать, чтобы ваш список чисел попал в список AppleScript. Вы поставите их вверху через запятую, заменив мои 10000, 20000, 30000.

Я называю список номеров "the_numbers". Назвав его свойством, мы сохраняем значение the_numbers от запуска к запуску. Если бы вы использовали мой сценарий как есть вместо своего «Без названия 3» в установленном вами правиле, при первом вызове сценария он будет работать с {10000, 20000, 30000}. При следующем запуске список будет {20000, 30000}. При следующем запуске будет {30000}. Также будет {30000} для всех последующих запусков. Я предполагаю/надеюсь, что у вас очень длинный список номеров, и вы не собираетесь исчерпать его.

Лучший сценарий сообщит вам, что список номеров закончился до последнего.