Как открыть ссылку в определенном окне Safari в macOS?

Это можно сделать с помощью приложения AppleScript, которое открывает ссылку в Safari и делает это приложение браузером по умолчанию.

Во время тестирования я нашел две версии: либо открывать в новых окнах, либо в новых вкладках, если в текущем пространстве уже есть окно.

• Откройте Script Editor.app (или даже лучше Script Debugger)

• Если вы хотите, чтобы ссылки открывались в новом окне, используйте этот

    on open location theURL    
        tell application "Safari"  
            make new document with properties {URL:theURL}  
            activate  
        end tell  
    end open location  

• Если вы хотите, чтобы ссылки открывались в новой вкладке (если окно доступно в текущем пространстве), используйте это:

    on open location theURL  
        tell application "System Events"  
            tell process "Safari"  
                try  
                    set frontWinName to name of window 1 
                on error  
                    my openNewWindow(theURL)  
                    return  
                end try  
            end tell  
        end tell  

        tell application "Safari"  
            try  
                tell (first window whose name is frontWinName and miniaturized is false)  
                    set current tab to make new tab with properties {URL:theURL}  
                    activate  
                end tell  
            on error  
                my openNewWindow(theURL)  
            end try  
        end tell  
    end open location  


    on openNewWindow(theURL)  
        tell application "Safari"  
            make new document with properties {URL:theURL}  
            activate  
        end tell  
    end openNewWindow  

• Сохранить как приложение

• Если вы не хотите, чтобы приложение отображалось в доке

  • Щелкните правой кнопкой мыши приложение, перейдите в пакет и найдитеInfo.plist

  • Добавьте это вInfo.plist

      <key>LSUIElement</key>  
      <true/>
  

• Установите приложение в качестве браузера по умолчанию (я использовал RCDefaultApp).

Если вы хотите увидеть, насколько раздражающим является поведение ссылки по умолчанию в macOS, я предлагаю через несколько часов вернуться к Safari в качестве браузера по умолчанию ...

Я все еще на 10.14.6 и не знаю возможных ограничений в Каталине.

Как разработчик, я исследовал возможность того, что расширения могут достичь того, чего вы хотите, всегда открывая новое окно при нажатии на ссылку, содержащуюся за пределами самого Safari. К сожалению, я не думаю, что такой подход будет возможен.

К сожалению, Safari не позволяет расширениям определять происхождение новой вкладки/окна. Под этим я подразумеваю, что новая вкладка может быть создана, потому что пользователь щелкает ссылку в электронном письме, щелкает ссылку в Safari, удерживая нажатой клавишу Command, открывает закладку Safari, щелкает ссылку в документе PDF или что-либо еще. одно из нескольких других действий, которые откроют страницу в новой вкладке. Независимо от метода, Safari не сообщает, как окно было открыто для расширения Safari.

Поскольку все эти события выглядят одинаково, ни одно расширение не может заставить ссылки из-за пределов Safari открываться в новых окнах, не затрагивая при этом ссылки, открытые другими способами (в том числе при просмотре в Safari).

Хотя изначально он не открывается в нужном вам окне, вы всегда можете захватить вкладку и переместить ее в другое окно Safari сразу после его открытия.

Не уверен, поможет это или нет, просто предложение.