С помощью документации Growl о поддержке AppleScript и небольшого обсуждения с Бартом Арондсоном и Эллиотом Б. в комментариях к вопросу я придумал следующий AppleScript.

Я сохранил этот сценарий в качестве агента приложения, который вы можете добавить к своим элементам входа в систему в « Системные настройки» → «Пользователи и группы» → «Элементы входа» .

По сути, это приложение работает, обнаруживая доступ к уникальному исполняемому файлу, связанному с использованием камеры. Всякий раз, когда к исполняемому файлу обращаются, приложение уведомляет об этом Growl:

Скачать

Важно знать, что этот скрипт отслеживает доступ к исполняемому файлу...

/System/Library/Frameworks/CoreMediaIO.framework/Versions/A/Resources/VDC.plugin/Contents/MacOS/VDC

Полный сценарий

-- check if growl is running in order to avoid the "Choose Application" dialog
tell application "System Events"
    set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
end tell

-- store time of last iSight access
global lastopened
set lastopened to do shell script "ls -lu /System/Library/Frameworks/CoreMediaIO.framework/Versions/A/Resources/VDC.plugin/Contents/MacOS/VDC | awk '{print $6,$7,$8}'"

-- make the application ready for use with growl
if isRunning then
    tell application id "com.Growl.GrowlHelperApp"

        -- make a list of all the notification types that this script will ever send
        set the allNotificationsList to ¬
            {"iSight access monitor"}

        -- register the script with growl
        register as application ¬
            "iSight access monitor" all notifications allNotificationsList ¬
            default notifications allNotificationsList ¬
            icon of application "FaceTime"

        -- send the first notification right after the application is started
        notify with name ¬
            "iSight access monitor" title ¬
            "iSight access monitor" description ¬
            "last iSight access: 
" & lastopened application name "iSight access monitor"
    end tell
end if

-- monitoring routine: checks every 10s if the VDC executable has been accessed
on idle
    tell application id "com.Growl.GrowlHelperApp"
        set newopen to do shell script "ls -lu /System/Library/Frameworks/CoreMediaIO.framework/Versions/A/Resources/VDC.plugin/Contents/MacOS/VDC | awk '{print $6,$7,$8}'"
        if (newopen is not equal to lastopened) then
            notify with name ¬
                "iSight access monitor" title ¬
                "iSight access monitor" description ¬
                "new iSight access: 
" & newopen application name "iSight access monitor"
            set lastopened to newopen
        end if
    end tell
    return 10 -- interval in seconds
end idle

Micro Snitch делает именно то, что я искал:

Вы когда-нибудь задумывались, записывает ли приложение звук через встроенный микрофон вашего Mac без вашего ведома? Или если камера снимает видео без уважительной причины?

С Micro Snitch больше нет сомнений. Это сверхлегкое приложение строки меню незаметно работает в фоновом режиме. Он отслеживает и сообщает о любой активности микрофона и камеры, чтобы помочь вам выяснить, не шпионит ли кто-то за вами.

Это не бесплатно (4,50 евро на момент написания статьи), но я думаю, что оно того стоит.

_{Никакой принадлежности, просто счастливый пользователь.}