Есть ли способ изменить устройство вывода звука через Applescript или оболочку?

Есть audiodeviceкоманда, доступная от whoshacks .

Использование:

• audiodeviceсписок устройств для ввода, вывода и системного звука
• audiodevice <port>отобразить аудиоустройство для выбранного порта
• audiodevice <port> listсписок доступных аудиоустройств для выбранного порта
• audiodevice <port> <device>установите выбранный порт для использования назначенного устройства («внутренний» выберет внутренние динамики или наушники, в зависимости от того, что активно)

Есть команда switchaudio-osx , которую необходимо скомпилировать из исходников или установить через homebrew (требуется установка Xcode):

brew install switchaudio-osx

Использование:

SwitchAudioSource [-a] [-c] [-t type] [-n] -s device_name

• -a: показывает все устройства
• -c: показывает текущее устройство
• -t type: тип устройства (ввод/вывод/система). По умолчанию для вывода.
• -n: переключает аудиоустройство на следующее
• -s device_name: устанавливает аудиоустройство на данное устройство по имени

Вот AppleScript, чтобы сделать это с помощью switchaudio-osx (просто замените XXXXXXX на имя устройства, которое вы можете получить, выполнив «SwitchAudioSource -a»):

on run {input, parameters}

    do shell script "/usr/local/bin/SwitchAudioSource -s 'XXXXXXXX'"

    return input
end run

Мне нужно было сочетание клавиш для изменения вывода звука — мне понравилась простота ответов AppleScript, которые я видел на форумах Stack Exchange, но мне не нравится идея жесткого кодирования имени устройства вывода/ввода, которое я хочу изменить. Также я не смог найти элегантного решения для переключения между тремя аудиовыходами с помощью if-else. Не говоря уже о том, что источник не всегда находится в списке вывода (например, наушники Bluetooth).

Поэтому я написал ниже, который просто перебирает все параметры и выбирает следующий источник в списке/первый источник в списке, если выбран последний вариант. Просто измените sourceToChangeпеременную с «Выход» на «Вход», если вы хотите создать еще один скрипт для переключения источников микрофона. Одним из недостатков этого подхода является то, что вы должны предоставить доступ «Управление своим компьютером» для любого приложения, которое вызывает этот рабочий процесс / быстрое действие. Я предполагаю, что это как-то связано с вызовом приложения «Системные события», но я не уверен в этом на 100%. Также не уверен на 100% в безопасности. Тем не менее, я надеюсь, что это поможет некоторым людям. Меня устраивает!

# loop thru all sound outputs in "System Preferences" > "Sound" > "Output"/"Input"

on run {input, parameters}
    
    set sourceToChange to "Output" # change me to "Input" or "Output"!
    
    tell application "System Preferences"
        run
        set current pane to pane "com.apple.preference.sound"
        
    end tell
    
    tell application "System Events"
        
        tell application process "System Preferences"
        
            repeat until exists tab group 1 of window "Sound" # prevent script from executing before Sound load
            
            end repeat
            
            tell tab group 1 of window "Sound"
                
                click radio button sourceToChange
                set soundOutputs to a reference to every row of table 1 of scroll area 1
                set activateSound to false
                set exitMe to false
                
                repeat with i from 1 to count of soundOutputs
                    
                    if activateSound is true then
                        
                        set exitMe to true
                        set selected of row i of table 1 of scroll area 1 to true
                        
                        # if attempted to set the line break before AirPlay devices to true, set the first row to true and exit
                        if (not selected of row i of table 1 of scroll area 1) then
                            set selected of row 1 of table 1 of scroll area 1 to true
                            
                        end if
                        
                    end if
                    
                    if (selected of row i of table 1 of scroll area 1) and (activateSound is false) and (exitMe is false) then
                        set activateSound to true
                        
                    end if
                    
                    if exitMe is true then
                        return
                        
                    end if
                    
                end repeat
                
                # Input doesn't suffer from the AirPlay linebreak issue so this catches an attempt to exit at the last row before setting selected to the first item
                set selected of row 1 of table 1 of scroll area 1 to true
                
            end tell
        end tell
    end tell
end run

https://github.com/deweller/switchaudio-osx

Чтобы установить открытый терминал и запуститьbrew install switchaudio-osx

Чтобы перечислить все источники для ввода/вывода, выполнитеSwitchAudioSource -a

Это приведет к выводу, аналогичному

External Microphone (input)
MacBook Pro Microphone (input)
External Headphones (output)
MacBook Pro Speakers (output)

Чтобы переключить микрофон на внешний микрофон, выполните следующую команду

SwitchAudioSource -t input -s 'External Microphone'

https://appsnomad.com/blog/how-to-change-audio-output-input-from-terminal-in-osx/3

Существует алоэ, платное приложение Ears за 5 долларов, которое сделает эту работу и может использоваться с командной строкой https://retina.studio/ears/.