Есть ли способ написать «чужое» изображение, чтобы камера Fujifilm X отображала его?

Рискуя просто сбросить нерелевантный код, вот программа Perl, которую я использовал для аналогичной цели — перенос изображений на принтер с помощью устройства чтения карт (до того, как я смог найти принтер достаточно близко, чтобы использовать его USB-соединение). У него есть некоторые встроенные предположения (что файловые системы карты могут монтироваться пользователем в /media/card/<card-type>), но вы должны иметь возможность отбросить mount/ umountчасть, если она вам не подходит. (Если бы я снова писал это с нуля, я бы, вероятно, использовал pmountвместо этого.)

Также есть попытка дать изображениям, отличным от JPEG, подходящий файл эскиза, как это предписано DCIM; Я могу подтвердить, что это работает на моей цифровой зеркальной фотокамере Canon, но я не могу вспомнить, проверял ли я это на Fuji. Если бы я это сделал, это было бы на компактной F30 или F60.

FWIW, мой скрипт чтения карт (не показан) удаляет каждое изображение из файловой системы карты, когда оно правильно записано в мой архивный каталог (и помечено как доступное только для чтения). У меня есть --keepвозможность переопределить это, что полезно при тестировании изменений в сценарии. Я никогда не переформатирую карты.

Код

#!/usr/bin/perl
use strict;
use Getopt::Long;

# Usage: write-image.pl file... dest
# dest is a dcf root directory - i.e. it contains a dcim subdir.

my $verbose = '';
my $rotate = '';
my $clear = '';

GetOptions ("clear!" => \$clear,
            "rotate!" => \$rotate,
            "verbose!" => \$verbose);

my $basedir = "/media/card";
if (@ARGV < 2) {
    die "not enough arguments\n";
}

my $dest = pop;
$dest = "$basedir/$dest" unless $dest =~ /^\//;

my $mounted = -d "$dest/dcim";
unless ($mounted) {
    print "mount $dest\n" if $verbose;
    system("mount", "$dest") == 0 or die;
}

if ($clear && -d "$dest/dcim") {
    clear(<$dest/dcim/*>);
}

# scan image directories
my $dirno = 99;
my $destdir;
foreach (<$dest/dcim/*>) {
    $dirno = $1 if /\/([1-9][0-9][0-9])/;;
    $destdir = $_ if /\/([1-9][0-9][0-9])linux$/;
}

unless ($destdir) {
    die if ++$dirno > 999;
    $destdir = "$dest/dcim/${dirno}linux";
    print "Adding new directory $destdir\n" if $verbose;
    -d "$dest/dcim" or mkdir"$dest/dcim" or die;
    mkdir $destdir or die;
}

# scan files
my $fileno = 0;
foreach (<$destdir/????[0-9][0-9][0-9][0-9].*>) {
    /\/....([0-9][0-9][0-9][0-9])\..*/;
    $fileno = $1 if $1 > $fileno;
}

sub clear(@) {
    my $f;
    foreach $f (@_) {
         if (-d $f) {
             &clear(<$f/*>);
             #print STDERR "rmdir  $f\n";
             rmdir $f;
         } else {
             #print STDERR "unlink $f\n";
             unlink $f;
         }
    }
}

#do it
foreach (@ARGV) {
    if (++$fileno > 9999) {
        die if ++$dirno > 999;
        $fileno = 1;
        $destdir = "$dest/dcim/${dirno}linux";
        mkdir $destdir or die;
    }
    my $destfile = sprintf "$destdir/img_%04d", $fileno;
    my $suffix = "";
    if (/\.[^.]+\Z/) {
        $suffix = $&;
    }
    #print "$_ -> $destfile$suffix\n" if $verbose;
    print "$_: " if $verbose;   # no newline!
    if ("$suffix" eq ".jpg") {
        if ($rotate) {
            system("( jpegtran -rot 90 -perfect $_ || djpeg $_ | pnmflip -cw | cjpeg -quality 95 -dct float -sample 1x1 ) > $destfile.jpg && exiftran -g -i $destfile.jpg") == 0 || die;
        } else {
            system("exiftran", "-g", "-o", "$destfile.jpg", "$_") == 0 || die;
            print sprintf(" -> img_%04d$suffix\n", $fileno) if $verbose;
        }
    } else {
        system("/bin/cp $_ $destfile$suffix") == 0 || die "$!\n";
        system("anytopnm $_ 2>&- | pnmscale -xysize 160 120 | pnmpad -width 160 -height 120 | pnmtojpeg >$destfile.thm") ==0 || die "$!\n";
        print "\n" if $verbose;
    }
}

unless ($mounted) {
    print "umount $dest\n" if $verbose;
    system("umount", "$dest") == 0 or die;
}

Еще раз прошу прощения за длину. Зато теперь должно быть понятно, куда записывать изображение в файловой системе карты: в частности, по стандарту DCIM , оно должно быть в DCIM/nnnAAAAA/AAAAnnnn.ext, где nчисловое, Aлюбой символ¹, и в extзависимости от того, сам ли это объект или отдельная миниатюра. Если имя не соответствует этому шаблону, камера, скорее всего, проигнорирует его.JPGTHM

Обратите также внимание на использование exiftran -gдля добавления миниатюры EXIF ​​(правильного размера) к изображению, у которого ее нет. Это, вероятно, важно для вашего использования, поскольку камеры, как правило, полагаются на миниатюру для предварительного просмотра изображения. Тот, который создан GIMP, вероятно, имеет неправильный размер и может привести к тому, что ваша камера проигнорирует изображение, отобразит заполнитель или даже сообщит об ошибке чтения.

¹ То есть любой символ из довольно ограниченного набора, разрешенного DCIM: 123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ_.

Я не знаю, что нужно, чтобы распознать "чужое" изображение, возможно, что-то в Exif... но для вашей цели просто создайте изображение с вашим сообщением, с соответствующим фоном, и сфотографируйте его при показе на экран домашнего компьютера. Потом уже в камеру.