Есть ли способ получить всплывающее уведомление на моем iPhone или iPad, когда приходит почта?

С выпуском iOS 5 почта теперь может отображаться как уведомление в виде всплывающего окна.

Перейдите в «Настройки»> «Уведомления»> «Почта»> выберите «Оповещения» в меню стиля оповещения.

тогда у вас будет что-то похожее на уведомление о сообщении, когда придет электронное письмо

Попробуйте BoxCar .

Я использую его аналогичным образом для уведомлений Twitter Direct Message.

Я использую комбинацию Notify и Prowl на запасном Mac. Я нашел так много других применений для Prowl, таких как отправка push-уведомлений из скрипта.

Не используйте стандартную конфигурацию Gmail с iPhone, используйте Google Sync.

Здесь: Google Sync: настройте свое устройство Apple для Google SyncShare Комментарий

Это не способ решить вашу проблему сейчас, но я считаю, что iOS 5 сможет делать то, что вы хотите, когда она будет выпущена этой осенью в соответствии с: http://www.apple.com/ios/ios5/features.html #уведомление

Я вижу скриншоты с почтовыми уведомлениями в верхней части экрана и считаю, что их можно настроить так, чтобы они были всплывающими окнами в текущем стиле для каждого приложения.

Я использую комбинацию правил Apple Mail, AppleScript и Howl (еще одно приложение для рычания, похожее на упомянутое выше Prowl).

Назовите правило Mail следующим образом: «growl-TestPost», как указано в AppleScript, затем настройте условия и запустите этот AppleScript для запуска. Затем настройте свой стиль отображения Growl, чтобы использовать стиль Howl (или Prowl).

Вот AppleScript, к сожалению, у меня нет информации об оригинальном авторском скрипте, который я модифицировал:

on run
    -- at current, the registration is done whenever you launch the script, 
    -- and also below whenever the the script itself is run by Mail
    -- (that let's users make new notification on the fly, sort of...)
    -- could probably find a more graceful semaphor, but...
    register()
end run

using terms from application "Mail"
    on perform mail action with messages messageList for rule theRule
        set theRuleName to name of theRule
        if theRuleName does not start with "growl-" then return

        register()
        -- extract notification type from rule name
        set noteType to characters 7 thru (length of theRuleName) of theRuleName as text
        repeat with thisMessage in messageList

            -- basic information for notification
            set theSender to sender of thisMessage
            set theSubject to subject of thisMessage
            set theText to (content of thisMessage)
            set tid to AppleScript's text item delimiters
            set AppleScript's text item delimiters to " "
            try
                set theSummary to (text items 1 through 20 of theText) as text
            on error
                set theSummary to theText
            end try
            set AppleScript's text item delimiters to tid

            -- notify
            tell application "GrowlHelperApp" to notify with name noteType ¬
                title noteType description ¬
                "From: " & theSender & return & "Subject: " & theSubject ¬
                application name "MailGrowl"
        end repeat
        -- if we want to coalesce or order the notifications, then we'd put the 
        -- notifications into an array above and notify GHA here.  I'm not completely
        -- on the structures that are required for grouped messages, though..
    end perform mail action with messages
end using terms from

to register()
    tell application "Mail"
        set ruleList to name of every rule whose name begins with "growl"
    end tell
    set noteTypes to {}
    repeat with theRuleName in ruleList
        set end of noteTypes to (characters 7 thru (length of theRuleName) of theRuleName as text)
    end repeat
    tell application "GrowlHelperApp"
        register as application "MailGrowl" all notifications noteTypes ¬
            default notifications noteTypes ¬
            icon of application "Mail"
    end tell
end register