Стабильная интерактивность кольцевого мира с другими объектами Солнечной системы

TL;DR: Да, спиральное движение вокруг мира-кольца возможно. Однако на больших расстояниях (≥ 0,04 а.е.) он далеко не равномерен.

Резюме результатов:

Для тороидального кольца с массой$M_R = 3 M_\text{star} = 3M_\odot$, центральный радиус$a = 1 \text{ AU}$и внутренний радиус$b = 10^{-4} a \simeq 15000\text{ km}$(отсюда плотность$\rho \sim 8800\text{ kg/m}^3$, сравнить с$\rho_{\text{Fe}}\sim 7800\text{ kg/m}^3$), связь между средним расстоянием от центрального кольца кольцевого мира и периодом времени представлена ​​​​следующим графиком:

$\lambda a$расстояние от центрального кольца. Уравнения аппроксимируются с использованием среднего (квадратичного) значения$\lambda$более 1 года. Медианное (пятиугольник) и стартовое (круг) значения$\lambda$также показаны. Столбики ошибок показывают минимальное и максимальное значение$\lambda$. Черный → без центральной звезды, оранжевый →$M_{\text{star}} = M_{\odot}$.

Траектория действительно винтовая.

Мы можем посмотреть на спроецированное поперечное сечение ниже. Центр кольца находится в$x=-1$(в масштабе$a$, не показано), центральное кольцо тора находится в$x=0$. Ясно, что «внутренние расстояния» больше, чем «внешние расстояния», как можно было бы наивно ожидать. Как и раньше, черный → без центральной звезды, оранжевый →$M_{\text{star}} = M_{\odot}$. Первый график полупрозрачный, поэтому вы можете увидеть оба сечения, увеличив масштаб.

Физика:

Для простоты рассмотрим точечную частицу; если спутник слишком велик (насколько велик?), возникнут сложности из-за предела Роша и т. д. Замените кольцевой мир (тор для расчета объема) его центральным кольцом для всех других расчетов. Пусть частица вылетает из$(x,y,z)=((1-\lambda) a, 0,0)$. Мы рассматриваем только режим$0.01 \leq \lambda \leq 0.1$. Нижний предел не позволяет частице распознать, что мир-кольцо был аппроксимирован кольцом, а верхний предел предотвращает существенное возмущение ее орбиты звездой.

Предположим, что первоначально лучевая скорость равна нулю. Тангенциальная скорость для орбиты вокруг звезды (изначально$v_y$) примерно должно быть$\sqrt{G M_{\text{star}}/((1-\lambda) a)}$. Орбитальная скорость вокруг кольцевого мира (изначально$v_z$) примерно должно быть$\sqrt{g((1-\lambda) a,0,0) \lambda a}$куда$g(x,y,z)$- это величина чистого гравитационного поля (также известного как ускорение под действием силы тяжести) в зависимости от положения.

Мы застряли без номера для$g((1-\lambda) a,0,0)$.

Электрический потенциал для кольца заряда$Q$дается как (ссылка 1):

Потенциал гравитационного кольца легко получить, подставив$\epsilon_0 \rightarrow -1/(4\pi G)$а также$Q\rightarrow M$в уравнении. Можно взять градиент (с$-$знак) и найти поле численно.

Или можно было бы пойти еще на несколько шагов и рассчитать все на самом деле. Используя уравнение, показанное ранее для одного значения$M_R$(оранжевый на графике), можно экстраполировать на другие значения$M_R$с использованием$1/T\propto\sqrt{M_R}$(так долго как$M_R$не намного меньше, чем$M_S$) в качестве

Реализация (Математика):

(Все в единицах СИ, если не указано иное.)

Сначала мы устанавливаем константы. Эллиптический интеграл для$V$более раннее несколько неприятно и требует времени для упрощения, поэтому я упростил его один раз и заменил определение выводом упрощения.

G = 6.674 10^-11;
EarthMass = 5.9722 10^24;
SolarMass = 333000 EarthMass;
RingMass = 3 SolarMass;
AU = 1.508 10^11;
a = 1 AU;
b = 10^-4 a;
day = 24*3600 // N;
year = 365.25 day;
\[Rho] = RingMass/((2 \[Pi] a) (\[Pi] b^2)) (* roughly 8800, Fe \[Rule] 7800 *) 
(* Math *)
VRing[r_, \[Phi]_, z_, 
   MR_] = -G MR/(2 \[Pi]) ((2 Sqrt[(
       a^2 + r^2 + z^2 - 2 a r Cos[\[Phi]])/((a - r)^2 + 
        z^2)] (EllipticF[\[Pi] - \[Phi]/2, -((
           4 a r)/((a - r)^2 + z^2))] + 
         EllipticF[\[Phi]/2, -((4 a r)/((a - r)^2 + z^2))]))/(Sqrt[
      a^2 + r^2 + z^2 - 2 a r Cos[\[Phi]]]));
VRingxyz[x_, y_, z_, MR_] = 
  TransformedField["Polar" -> "Cartesian", 
   VRing[r, \[Phi], z, MR], {r, \[Phi]} -> {x, y}];
Vtot[x_, y_, z_, MR_, MS_] = -G MS/Norm[{x, y, z}] + 
   VRingxyz[x, y, z, MR];
gRing[x_, y_, z_, MR_] = -Grad[VRingxyz[x, y, z, MR], {x, y, z}];
gtot[x_, y_, z_, MR_, 
   MS_] = -Grad[Vtot[x, y, z, MR, MS], {x, y, z}] /. 
   Abs[p_] Abs'[p_] -> p;
gtotmag[x_, y_, z_, MR_, MS_] = Norm[gtot[x, y, z, MR, MS]];

Давайте быстро проверим работоспособность и посмотрим, соответствует ли гравитационное поле ожидаемому.

imgWidth = 2160;
plotAndExport[fname_, 
   plot_] := (Export[NotebookDirectory[] <> fname, 
    Rasterize[plot, ImageSize -> imgWidth]]; plot);
fieldPlotXLim = 1.5/Sqrt[2]; fieldPlotYLim = fieldPlotXLim;
splot = plotAndExport["field.png", #] &@
   Show[StreamPlot[
     Chop@(gtot[x1 a, y1 a, 0, RingMass, SolarMass][[1 ;; 2]])
     , {x1, -fieldPlotXLim, fieldPlotXLim}, {y1, -fieldPlotYLim, 
      fieldPlotYLim}
     , BaseStyle -> {FontSize -> 24}]];

Выглядит хорошо. На первом графике показан «расход» поля (размеры стрелок неверны). Величина поля вдоль$x$также показана ось.

Теперь мы реализуем решатели для траектории частицы.

(* Trajectory solvers with initial conditions *)

xi[\[Lambda]_] := a (1 - \[Lambda]);
yi[\[Lambda]_] := 0.;
zi[\[Lambda]_] := 0.;
vxi[\[Lambda]_] := 0.;
vyi[\[Lambda]_] := Sqrt[G SolarMass/Abs[xi[\[Lambda]]]];
vzi[\[Lambda]_, MR_] := 
  Sqrt[Abs[a - xi[\[Lambda]]] Norm@
     gRing[xi[\[Lambda]], yi[\[Lambda]], zi[\[Lambda]], MR]];
ringSol[\[Lambda]_, MR_, time_] := NDSolve[
   Flatten@{Thread[{xs''[t], ys''[t], zs''[t]} == 
       gRing[xs[t], ys[t], zs[t], MR]],
     xs'[0] == vxi[\[Lambda]], ys'[0] == vyi[\[Lambda]], 
     zs'[0] == vzi[\[Lambda], MR], 
     xs[0] == xi[\[Lambda]], ys[0] == yi[\[Lambda]], 
     zs[0] == zi[\[Lambda]]},
   {xs, ys, zs}, {t, 0, time}];

xiFull[\[Lambda]_] := xi[\[Lambda]];
yiFull[\[Lambda]_] := yi[\[Lambda]];
ziFull[\[Lambda]_] := zi[\[Lambda]];
vxiFull[\[Lambda]_] := vxi[\[Lambda]];
vyiFull[\[Lambda]_, MS_] := Sqrt[G MS/Abs[xi[\[Lambda]]]];
vziFull[\[Lambda]_, MR_, MS_] := 
  Sqrt[Abs[a - xi[\[Lambda]]] Norm@
     gtot[xi[\[Lambda]], yi[\[Lambda]], zi[\[Lambda]], MR, MS]];
fullSol[\[Lambda]_, MR_, MS_, time_, \[Epsilon]_] := NDSolve[
   Flatten@{Thread[{xs''[t], ys''[t], zs''[t]} == 
       gtot[xs[t], ys[t], zs[t], MR, MS]]
     , xs'[0] == vxiFull[\[Lambda]], ys'[0] == vyiFull[\[Lambda], MS],
      zs'[0] == (1 + \[Epsilon]) vziFull[\[Lambda], MR, MS]
     , xs[0] == xiFull[\[Lambda]], ys[0] == yiFull[\[Lambda]], 
     zs[0] == ziFull[\[Lambda]]}
   , {xs, ys, zs}, {t, 0, time}
   ];

appendVelocities[solution_] := 
 Append[solution, {vx -> xs', vy -> ys', vz -> zs'} /. solution]

Нам понадобится куча функций для анализа временного периода.

(* Examining the period T of rotation about the ring *)
(* findPeriod and reconstruct copied from \
https://mathematica.stackexchange.com/a/38221/9332 *)

findPeriod[data_, threshold_] := 
 Module[{fs, s1, s = {}, i, a0f, af, pf, pos, fr, frpos, fdata, 
   fdatac, n, per}, n = Length[data];
  fs = Fourier[data];
  s1 = Drop[fs, -Floor[Length[fs]/2]];
  For[i = 1, i < Length[s1], i++, 
   If[Abs[fs][[i + 1]] > threshold, AppendTo[s, i + 1]]];
  a0f = Abs[fs[[1]]]/Sqrt[n];
  af = 2/Sqrt[n] Abs[fs][[s]];
  pf = Arg[fs][[s]];
  {a0f, Transpose[{s, af, pf}]}]
reconstruct[data_, fp_] := Module[{n}, n = Length[data];
   Show[ListLinePlot[data, PlotStyle -> Black], 
    Plot[fp[[1]] + 
      Sum[fp[[2, j, 2]] Cos[
         2 Pi (fp[[2, j, 1]] - 1)/n t - fp[[2, j, 3]]], {j, 1, 
        Length[fp[[2]]]}], {t, 0, n}, PlotStyle -> Red]]];
getOrbitPeriod[solution_, totalTime_, timeStep_] := Module[{data},
   data = 
    Flatten@Table[
      zs[t timeStep] /. solution, {t, 0, totalTime/timeStep}];
   (* Not strictly correct as there are many frequencies but good \
enough for first approximation *)

   totalTime/(timeStep Sort[
        findPeriod[data, 10^8][[2]], #1[[2]] > #2[[2]] &][[1, 1]])];

(* The period T is observed to be linear in \[Lambda] *)
\
\[Lambda]TFit[\[Lambda]list_, Tlist_] := 
  LinearModelFit[
   Transpose@{\[Lambda]list, Tlist}, \[Lambda], \[Lambda]];

setGraphFontSize = BaseStyle -> {FontSize -> 12};
graphLineWidth = 0.003;
graphMarkerLineWidth = 0.005;
graphMarkerSize = 6;
opacity = 0.5;
polygonMarker[color_, n_] := 
  Graphics[{EdgeForm[{Thickness -> graphMarkerLineWidth, color}], 
    FaceForm[None], Polygon[CirclePoints@n]}, 
   ImageSize -> graphMarkerSize];

coloredListPlot[x_, y_, color_, PM_] := 
  ListPlot[Transpose@{x, y}, PlotStyle -> color, PlotMarkers -> PM];
Needs["ErrorBarPlots`"]
\[Lambda]TFitGraph[{\[Lambda]list_, min\[Lambda]_, max\[Lambda]_, 
   mean\[Lambda]_, median\[Lambda]_}, Tlist_, color_] := 
 Module[{model = \[Lambda]TFit[mean\[Lambda], Tlist]},
  Show[
   Plot[Normal[model], {\[Lambda], 0.01, Max[mean\[Lambda]]}
    , PlotStyle -> {color, Dashed, Thickness -> graphLineWidth}, 
    AxesLabel -> {"\[Lambda]", "T (days)"}
    , PlotLegends -> SwatchLegend[{color}, {Normal[model]}]
    , Evaluate@setGraphFontSize, 
    PlotRange -> {{0, Automatic}, {0, Automatic}}]
   , ErrorListPlot[
    (({{#1, #4}, ErrorBar[{#2 - #1, #3 - #1}, {0, 0}]} &) @@ # &) /@ 
     Transpose@{mean\[Lambda], min\[Lambda], max\[Lambda], Tlist}
    , PlotStyle -> {color, Thickness -> graphLineWidth}, 
    PlotMarkers -> polygonMarker[color, 4]]
   , coloredListPlot[\[Lambda]list, Tlist, 
    color, {Automatic, graphMarkerSize}]
   , coloredListPlot[median\[Lambda], Tlist, color, 
    polygonMarker[color, 5]]
   ]]

Наконец, мы запускаем решатели и видим данные.

(* Actually run simulations *)

ringSolutionTime = year;
ring\[Lambda]list = Range[0.01, 0.1, 0.01];

AbsoluteTiming[
  ringSolutions = 
   Flatten@appendVelocities@ringSol[#, RingMass, ringSolutionTime] & /@
     ring\[Lambda]list
  ][[1]]

ringPeriods = 
  getOrbitPeriod[#, ringSolutionTime, day] & /@ ringSolutions;
{ringMaxDist, ringMinDist, ringMeanDist, ringMedianDist} = 
  Transpose[distCalc[#, ringSolutionTime, day/24] & /@ ringSolutions];

TableForm@{ring\[Lambda]list, ringMaxDist, ringMinDist, 
  ringMeanDist, ringMedianDist}

fullSolutionTime = year;
full\[Lambda]list = ring\[Lambda]list + 0.005;
AbsoluteTiming[
  fullSolutions = 
   Flatten@appendVelocities@
       fullSol[#, RingMass, SolarMass, fullSolutionTime, 0] & /@ 
    full\[Lambda]list
  ][[1]]

fullPeriods = getOrbitPeriod[#, fullSolutionTime, day] & /@ fullSolutions;
{fullMaxDist, fullMinDist, fullMeanDist, fullMedianDist} = 
  Transpose[distCalc[#, fullSolutionTime, day/24] & /@ fullSolutions];

TableForm@{full\[Lambda]list, fullMaxDist, fullMinDist, 
  fullMeanDist, fullMedianDist}

Создание$T$против$\lambda$построить и увидеть траекторию (кратко графики).

plotAndExport["Tvl.png", #] &@
 Show[
  \[Lambda]TFitGraph[{ring\[Lambda]list, ringMinDist, ringMaxDist, 
    ringMeanDist, ringMedianDist}, ringPeriods, Black]
  , \[Lambda]TFitGraph[{full\[Lambda]list, fullMinDist, fullMaxDist, 
    fullMeanDist, fullMedianDist}, fullPeriods, Orange]
  , PlotRange -> {{0, Automatic}, {0, Automatic}}
  ]
plotAndExport["traj.png", #] &@
 Show[GraphicsGrid[{{
     trajectory[full\[Lambda]list[[1]], fullSolutions[[1]], 
      fullSolutionTime/7]
     , trajectory[full\[Lambda]list[[1]], fullSolutions[[1]], 
      fullSolutionTime]
     }}]]

Использованная литература:

1. http://physics.oregonstate.edu/portfolios/Activities/EMActivities/ElectricPotentialRing/RingVSolutions070701.pdf

В этом вопросе есть аспекты, на которые довольно сложно ответить. Физическая демонстрация заряженных капель, вращающихся вокруг заряженной вязальной спицы, дает разумное представление о концепции, которую вы пытаетесь рассмотреть. Любой ответ должен будет заменить гравитационное поле капель и электростатическое поле вязальной спицы. Это может быть не так просто. Любой, кто знает, что я ошибаюсь в этом предложении, пожалуйста, прыгайте и уничтожьте его.

Предполагается, что мир-кольцо должен быть массивным, чтобы планета, похожая на Землю, вращалась по спиральной орбите вокруг мира-кольца. Хотя можно предположить, что планета, похожая на Землю, имеет массу, эквивалентную массе Земли, это самая простая часть. Теперь рассмотрим неизвестные факторы в этой модели.

Масса кольцевого мира неизвестна. Скорость земной планеты неизвестна. Масса мира-кольца будет определять гравитационную силу, действующую на планету, чтобы удерживать ее на орбите мира-кольца. В то время как скорость планеты будет определять ее вероятность сохранения своей орбиты вокруг кольца.

Это говорит о том, что кольцевой мир должен быть действительно чрезвычайно массивным. Вполне вероятно, что масса мира-кольца будет порядка массы Солнца. То есть масса, подобная массе Солнца. В этом случае кольцевой мир должен быть сделан из сверхплотной материи типа, предложенного Робертом Л. Форвардом в его спекулятивной статье «Физика вдали» (« Аналог» , август 1975 г., стр. 147–166).

Планета должна будет двигаться с большой скоростью. Это много по сравнению с обычными планетарными орбитами. Земля вращается вокруг Солнца со скоростью 30 км/с. Однако придумать способ осмыслить взаимосвязь между массой мира-кольца и скоростью планеты по спиральной орбите непросто. Это зависит от распределения массы по длине мира-кольца и силы, которую она оказывает на планету с массой Земли, так что планета может удерживаться на спиральной орбите вокруг мира-кольца.

Одна вещь, которая вызывает беспокойство, это тот факт, что все заряженные капли в конечном итоге падают на заряженную вязальную спицу. Если такое же поведение применимо к планете на спиральной орбите вокруг массивного мира-кольца, то планета в конечном итоге рухнет на сверхплотную поверхность мира-кольца. Хотя это захватывающе и драматично, это не будет хорошей новостью ни для кого из жителей планеты.

Любой ответ, который может дать решение проблемы, предложенной в вопросе, потребует разработки модели, описывающей гравитационные и скоростные отношения между миром-кольцом и планетой на спиральной орбите, чтобы определить временную шкалу орбиты планеты и, возможно, устойчивость этой системы. В настоящее время неизвестные факторы затрудняют определение ответа. Этот ответ исследовал ограничивающие факторы проблемы, но не смог предложить решение вопроса ОП.

ДОПОЛНЕНИЕ:

Основная проблема заключается в форме гравитационного поля массивного кольцевого мира. У планет и звезд гравитационное поле сосредоточено вокруг точечного источника. Поле кольцевого мира имеет протяженный источник. Планета может иметь две составляющие скорости. Одна - орбитальная скорость вокруг звезды, другая - орбитальная скорость вокруг мира-кольца. Это дало бы спиральную орбиту.

Теперь это соображение предлагает возможное решение. Предположим, что масса кольцевого мира равна массе планеты с массой Земли в полосе шириной 12 742 километра. Эта ширина выбрана потому, что это диаметр земной планеты. Это дает разумное приближение для минимального гравитационного поля массивного кольцевого мира, чтобы удерживать планету с массой Земли на орбите вокруг него. Предполагая, что он имеет орбитальную скорость 8 км/с, так как это орбитальная скорость, необходимая для поддержания спутника на орбите вокруг планеты, похожей на Землю (в данном случае полоса кольцевого мира).

Планета, вращающаяся вокруг мира-кольца, будет иметь гелиоцентрическую орбитальную скорость 30 км/с, что точно такое же, как у планеты Земля, и это только одна составляющая скорости планеты. Другая составляющая скорости поддерживает вращение планеты по кольцу. Суммарные скорости образуют спиральную орбиту вокруг мира-кольца.

OP может подключить любые измерения мира-кольца, чтобы установить размер орбиты вокруг мира-кольца.

Быстрый расчет показывает, что масса мира-кольца будет равна 73 966,237 массы Земли (где 1 астрономическая единица равна 150 000 00 километров). Просто разделите длину окружности кольца на 12 742, потому что мы предположили, что каждая полоса длиной 12 742 километра имеет массу Земли.

Орбита планеты вокруг кольцевого мира будет высокой. Возможно, что-то вроде 48-часовой орбиты, которая удержит планету далеко от мира-кольца. Это должно обезопасить планету. Кроме того, кольцевой мир должен иметь узкую ширину. Например, около 12 000 км, примерно диаметр Земли. Опять же, это делается для того, чтобы сделать спиральную орбиту планеты безопасной. Радиус орбиты от кольца составляет 220 015,79 км. Навскидку неясно, жизнеспособна ли эта орбита. Примечание: предполагается, что орбитальная скорость равна 8 км/с.